#$Id: PKGBUILD 139632 2015-09-08 17:20:56Z dwallace $
# Maintainer: Daniel Wallace < danielwallace at gtmanfred dot com>
# Contributor: Trizen <echo dHJpemVueEBnbWFpbC5jb20K | base64 -d>

pkgname=youtube-viewer
epoch=1
pkgver=3.1.9
pkgrel=1
pkgdesc="A command line utility for viewing youtube-videos in MPlayer."
arch=('any')
url="https://github.com/trizen/youtube-viewer"
license=('GPL3')
source=("https://github.com/trizen/$pkgname/archive/$pkgver.tar.gz")
sha256sums=('7a4dec0a34fd632520986fbeebe4df14b5bc0aaee6b814e1eec6aa9b2b09f5ac')

depends=('perl>=5.16.0' 'perl-data-dump' 'perl-json' 'perl-lwp-protocol-https' 'perl-libwww')
optdepends=('vlc: for playing videos'
			'mplayer: for playing videos'
			'perl-term-readkey: to get the terminal width size'
            'perl-term-readline-gnu: for a better STDIN support'
            'perl-lwp-protocol-https: for login and https support'
            'gcap: for retrieving Youtube closed captions. [in AUR]')


build() {
    cd "$srcdir/$pkgname-$pkgver/"

    perl Makefile.PL INSTALLDIRS=vendor
}

check(){
    cd "$srcdir/$pkgname-$pkgver/"

    make test
}

package() {
    cd "$srcdir/$pkgname-$pkgver/"

    make install DESTDIR=$pkgdir
    rm -r "$pkgdir/usr/lib/"
}
