# $Id: PKGBUILD 138574 2015-08-20 21:18:30Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=vapoursynth-plugin-lsmashsource
pkgver=785
pkgrel=2
pkgdesc='L-SMASH source plugin for Vapoursynth'
arch=('i686' 'x86_64')
url='https://github.com/VFR-maniac/L-SMASH-Works'
license=('custom')
depends=('vapoursynth'
         'liblsmash.so')
makedepends=('git')
_commit='2a6cadfacc9597d008fb60d479a565236ddf5f8e'
source=("vapoursynth-plugin-lsmashsource::git+https://github.com/VFR-maniac/L-SMASH-Works.git#commit=${_commit}")
sha256sums=('SKIP')

build() {
  cd vapoursynth-plugin-lsmashsource/VapourSynth

  ./configure \
    --prefix='/usr'
  make
}

package(){
  cd vapoursynth-plugin-lsmashsource/VapourSynth

  make DESTDIR="${pkgdir}" install

  install -dm 755 "${pkgdir}"/usr/share/doc/vapoursynth/plugins/lsmashsource
  install -m 644 README "${pkgdir}"/usr/share/doc/vapoursynth/plugins/lsmashsource/

  install -dm 755 "${pkgdir}"/usr/share/licenses/vapoursynth-plugin-lsmashsource
  install -m 644 LICENSE "${pkgdir}"/usr/share/licenses/vapoursynth-plugin-lsmashsource/
}

# vim: ts=2 sw=2 et:
