# $Id: PKGBUILD 135144 2015-06-10 15:17:46Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Alessio Sergi <asergi at archlinux dot us>

pkgname=synapse
pkgver=0.2.99.1
pkgrel=1
pkgdesc="A semantic file launcher"
arch=('i686' 'x86_64')
url="https://launchpad.net/synapse-project"
license=('GPL3')
depends=('libkeybinder3' 'hicolor-icon-theme' 'json-glib' 'libgee' 'libnotify' \
         'zeitgeist' 'rest' 'xdg-utils')
makedepends=('intltool' 'vala')
optdepends=('banshee: banshee plugin'
            'bc: calculator plugin'
            'devhelp: documentation plugin'
            'gnome-screensaver: screensaver plugin'
            'gnome-dictionary: dictionary plugin'
            'openssh: ssh plugin'
            'pastebinit: pastebin plugin'
            'rhythmbox: rhythmbox plugin'
            'xnoise: xnoise plugin')
install=$pkgname.install
source=("https://launchpad.net/$pkgname-project/0.3/$pkgver/+download/$pkgname-$pkgver.tar.xz")
sha1sums=('c0b660b3376598c9ce5e13b9f3da13d660beb63d')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}

# vim:set ts=2 sw=2 et:
