# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Firef0x <Firefgx (at) gmail (dot) com>
# Contributor: sh0 <mee@sh0.org>
# Contributor: Lekensteyn <lekensteyn@gmail.com>

pkgname=smali
pkgver=2.1.0
pkgrel=1
pkgdesc="An assembler/disassembler for Android's dex format"
url="https://github.com/JesusFreke/smali"
arch=('any')
license=('BSD')
depends=('java-runtime' 'bash')
makedepends=('java-environment' 'gradle')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/JesusFreke/${pkgname}/archive/v${pkgver}.tar.gz)
sha512sums=('f0b565b82f02dbb963286d0ff9bf7dfbd468143a49e9320715a5fbd79472e5e1b383876cec4abe8b2fe1ee2342ad055e304911ef5a7057742674438769295d17')

prepare() {
  cd ${pkgname}-${pkgver}
  for file in baksmali smali; do
    # prevent from printing path on launch
    sed '/echo ${newProg}/d' -i scripts/${file}
    # fix ls path
    sed 's|/bin/ls|/usr/bin/ls|' -i scripts/${file}
  done
}

build() {
  cd ${pkgname}-${pkgver}
  gradle --gradle-user-home=. build
}

check() {
  cd ${pkgname}-${pkgver}
  gradle --gradle-user-home=. test
}

package() {
  cd ${pkgname}-${pkgver}
  install -d "${pkgdir}/usr/bin"
  for file in baksmali smali; do
    install -Dm 644 "${file}/build/libs/${file}-${pkgver}-dev.jar" "${pkgdir}/usr/share/java/${pkgname}/${file}.jar"
    install -Dm 755 scripts/${file} "${pkgdir}/usr/share/java/${pkgname}/${file}"
    ln -s "/usr/share/java/${pkgname}/${file}" "${pkgdir}/usr/bin/${file}"
  done
  install -Dm 644 NOTICE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: ts=2 sw=2 et:
