# $Id: PKGBUILD 144984 2015-10-26 00:54:59Z anatolik $
# Maintainer: Anatol Pomozov
# Contributor: Benjamin Chrétien <chretien + aur [at] lirmm [dot] fr>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
# Contributor: Rasi <rasi@xssn.at>
# Contributor: Sean Pringle <sean.pringle@gmail.com>
# Contributor: SanskritFritz (gmail)

pkgname=rofi
pkgver=0.15.10
pkgrel=1
pkgdesc='Popup window switcher roughly based on superswitcher, requiring only xlib and xft'
arch=(i686 x86_64)
url='https://davedavenport.github.io/rofi/'
license=(MIT)
depends=(libx11 libxft freetype2 libxdg-basedir libxinerama pango startup-notification)
makedepends=(i3-wm)
optdepends=('i3-wm: use as a window switcher')
source=(rofi-$pkgver.zip::https://github.com/DaveDavenport/rofi/archive/$pkgver.zip)
sha256sums=('3db53eb4ea2c7073db34f0acdcb384febbe9dc48c5ffcc4d4a522f1dcf7330f1')

build() {
  cd rofi-$pkgver
  autoreconf -i
  ./configure --prefix=/usr
  make
}

package() {
  cd rofi-$pkgver
  make install install-man DESTDIR="$pkgdir"

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/rofi/COPYING"
  install -dm755 "$pkgdir/usr/share/doc/rofi/examples"
  install -Dm755 Examples/*.sh "$pkgdir/usr/share/doc/rofi/examples"
}
