# Maintainer: schuay <jakob.gruber@gmail.com>
# Previous maintainer: Roman Zimbelmann <romanz@lavabit.com>

pkgname=ranger
pkgver=1.7.2
pkgrel=1
pkgdesc='A simple, vim-like file manager'
arch=('any')
url='http://ranger.nongnu.org'
license=('GPL')
depends=('python')
optdepends=(
    'python-chardet: in case of encoding detection problems'
    'sudo: to use the "run as root"-feature'
    'libcaca: for ASCII-art image previews'
    'highlight: for syntax highlighting of code'
    'atool: for previews of archives'
    'w3m: for previews of images and html pages'
    'lynx: for previews of html pages'
    'elinks: for previews of html pages'
    'poppler: for pdf previews'
    'transmission-cli: for viewing bittorrent information'
    'mediainfo: for viewing information about media files'
    'perl-image-exiftool: for viewing information about media files')
conflicts=('ranger-git')
source=("http://ranger.nongnu.org/${pkgname}-${pkgver}.tar.gz")

package() { 
  cd "${srcdir}/${pkgname}-${pkgver}"

  # Replace "python" with the python binary you want ranger to use!
  # (python 2.6 and >=3.1 supported, below 2.6 will certainly not work.)
  python setup.py -q install --root="${pkgdir}" --optimize=1
}

md5sums=('cc436fe2035a024755a1cad255bffaaf')
