# $Id: PKGBUILD 144333 2015-10-18 16:34:00Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Simon Hanna <simon dot hanna AT serve-me DOT info>

pkgbase=python-zope-event
pkgname=('python-zope-event' 'python2-zope-event')
pkgver=4.1.0
pkgrel=1
pkgdesc="Provides a simple event system"
arch=(any)
license=('ZPL')
url="https://github.com/zopefoundation/zope.event"
makedepends=('python-setuptools' 'python2-setuptools')
source=("https://github.com/zopefoundation/zope.event/archive/${pkgver}.tar.gz")
sha256sums=('a85cb6fd0e48e1147061eb0ecab57b9cc90f4c3b5609d63e5694a2d8de28ef47')
makedepends=('python-setuptools' 'python2-setuptools')

prepare() {
  cp -a zope.event-${pkgver}{,-py2}
}

build() {
  cd "${srcdir}/zope.event-${pkgver}"
  python setup.py build

  cd "${srcdir}/zope.event-${pkgver}-py2"
  python2 setup.py build
}

check() {
  cd "${srcdir}/zope.event-${pkgver}"
  python setup.py test

  cd "${srcdir}/zope.event-${pkgver}-py2"
  python2 setup.py test
}

package_python-zope-event() {
  depends=('python')
  cd "$srcdir/zope.event-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-zope-event() {
  depends=('python2')
  cd "$srcdir/zope.event-$pkgver"
  python2 setup.py install --root="$pkgdir/" --optimize=1
}

# vim:set ts=2 sw=2 et:
