# $Id: PKGBUILD 142619 2015-10-01 16:10:14Z fyan $
# Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Aaron DeVore <aaron.devore@gmail.com>
# Contributor: tocer <tocer.deng@gmail.com>
# Contributor: Piotr Beling <qwak@stud.ics.p.lodz.pl>
# Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>

pkgbase=python-xlrd
pkgname=('python2-xlrd' 'python-xlrd')
pkgver=0.9.4
pkgrel=2
pkgdesc="Library for developers to extract data from Microsoft Excel (tm) spreadsheet files"
arch=('any')
url="http://www.python-excel.org/"
license=('BSD')
makedepends=('python2-setuptools' 'python-setuptools')
source=("https://pypi.python.org/packages/source/x/xlrd/xlrd-${pkgver}.tar.gz")
md5sums=('911839f534d29fe04525ef8cd88fe865')

build() {
  cd "$srcdir"
  cp -a xlrd-${pkgver} xlrd-py2-${pkgver}

  msg "Building Python2"
  cd "$srcdir"/xlrd-py2-${pkgver}
  python2 setup.py build

  msg "Building Python3"
  cd "$srcdir"/xlrd-${pkgver}
  python setup.py build
}

package_python2-xlrd() {
  depends=('python2')

  cd "$srcdir"/xlrd-py2-${pkgver}

  python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
  mv "$pkgdir/usr/bin/runxlrd"{,2}.py

  install -D -m644 "xlrd/licences.py" "$pkgdir/usr/share/licenses/$pkgname/licences.py"
}

package_python-xlrd() {
  depends=('python')

  cd "$srcdir"/xlrd-${pkgver}

  python setup.py install --skip-build --root="$pkgdir" --optimize=1

  install -D -m644 "xlrd/licences.py" "$pkgdir/usr/share/licenses/$pkgname/licences.py"
}

