# $Id: PKGBUILD 142611 2015-10-01 16:10:06Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Bence Balint <balintbence1337@gmail.com>

pkgbase=python-w3lib
pkgname=('python-w3lib' 'python2-w3lib')
pkgver=1.12.0
pkgrel=2
pkgdesc="Library of web-related functions"
arch=('any')
license=('BSD')
url="http://w3lib.readthedocs.org"
makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six')
# checkdepends=('python-pytest' 'python2-pytest')
source=("https://pypi.python.org/packages/source/w/w3lib/w3lib-${pkgver}.tar.gz"
        LICENSE)
md5sums=('c2545617229b3fc72d59afed85b18035'
         '8a9dbf92a1904187a362d3fe098d4a1f')

prepare() {
  cp -a w3lib-$pkgver{,-py2}
}

check() {
  # Tests not included

  cd "$srcdir/w3lib-${pkgver}"
  # py.test

  cd "$srcdir/w3lib-${pkgver}-py2"
  # py.test2
}

package_python-w3lib() {
  depends=('python-six')

  cd "${srcdir}/w3lib-${pkgver}"
  python setup.py install --root="${pkgdir}" --optimize=1
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-w3lib() {
  depends=('python2-six')

  cd "${srcdir}/w3lib-${pkgver}-py2"
  python2 setup.py install --root="${pkgdir}" --optimize=1
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
