# $Id: PKGBUILD 143187 2015-10-07 02:03:33Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-pytest-django
pkgname=('python-pytest-django' 'python2-pytest-django')
pkgver=2.9.1
pkgrel=1
pkgdesc="A Django plugin for py.test"
arch=('any')
license=('BSD')
url="https://github.com/pytest-dev/pytest-django"
makedepends=('python-pytest' 'python2-pytest' 'git')
checkdepends=('python-django' 'python2-django' 'python-pytest-xdist' 'python2-pytest-xdist'
              'twine' 'python2-twine' 'python-south' 'python2-south')
source=("git+https://github.com/pytest-dev/pytest-django.git#tag=$pkgver")
#source=("git+https://github.com/pytest-dev/pytest-django.git#commit=$_commit")
sha512sums=('SKIP')

prepare() {
  cp -a pytest-django{,-py2}
}

build() {
  cd "$srcdir/pytest-django"
  python setup.py build

  cd "$srcdir/pytest-django-py2"
  python2 setup.py build
}

check() {
  # Hack entry points by installing it

  cd "$srcdir/pytest-django"
  python setup.py install --root="$PWD/tmp_install" --optimize=1
  PYTHONPATH="$PWD/tmp_install/usr/lib/python3.5/site-packages:$PYTHONPATH:$PWD" \
  DJANGO_SETTINGS_MODULE=pytest_django_test.settings_sqlite \
    py.test tests || warning "Tests failed"

  cd "$srcdir/pytest-django-py2"
  python2 setup.py install --root="$PWD/tmp_install" --optimize=1
  PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages:$PYTHONPATH:$PWD" \
  DJANGO_SETTINGS_MODULE=pytest_django_test.settings_sqlite \
    py.test2 tests
}

package_python-pytest-django() {
  depends=('python-pytest')

  cd pytest-django
  python setup.py install --root="${pkgdir}" --optimize=1
  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-pytest-django() {
  depends=('python2-pytest')

  cd pytest-django-py2
  python2 setup.py install --root="${pkgdir}" --optimize=1
  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
