# $Id: PKGBUILD 142694 2015-10-01 16:39:16Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-plop
pkgname=(python-plop python2-plop)
pkgver=0.3.0
pkgrel=1
pkgdesc="Python Low-Overhead Profiler"
arch=('any')
license=('MIT')
url="https://github.com/bdarnell/plop"
makedepends=('python-tornado' 'python2-tornado' 'python-six' 'python2-six'
             'python-setuptools' 'python2-setuptools')
source=("https://pypi.python.org/packages/source/p/plop/plop-${pkgver}.tar.gz")
md5sums=('4a313d6a8dd59ac48cfa3af426d197fc')

prepare() {
  cp -a plop-$pkgver{,-py2}
}

build() {
  cd "$srcdir/plop-${pkgver}"
  python setup.py build

  cd "$srcdir/plop-${pkgver}-py2"
  python2 setup.py build
}

check() {
  cd "$srcdir/plop-${pkgver}"
  python -m plop.test.runtests

  cd "$srcdir/plop-${pkgver}-py2"
  python2 -m plop.test.runtests
}

package_python-plop() {
  depends=('python-six' 'python-tornado')

  cd "${srcdir}/plop-${pkgver}"
  python setup.py install --root="${pkgdir}" --optimize=1
  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}

package_python2-plop() {
  depends=('python2-six' 'python2-tornado')

  cd "${srcdir}/plop-${pkgver}-py2"
  python2 setup.py install --root="${pkgdir}" --optimize=1
  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}
