# $Id: PKGBUILD 144347 2015-10-19 00:02:23Z kkeen $
# Maintainer: Kyle Keen <keenerd@gmail.com>

pkgbase=python-path
pkgname=(python-path python2-path)
pkgver=8.1.2
pkgrel=1
pkgdesc="Aka path.py, implements path objects as first-class entities"
arch=('any')
url="http://ipython.org"
license=('MIT')
depends=('python')
makedepends=('python-setuptools' 'python2-setuptools')
source=("https://pypi.python.org/packages/source/p/path.py/path.py-$pkgver.tar.gz")
md5sums=('31d07ac861284f8148a9041064852371')


prepare() {
  cd "$srcdir"
  cp -r path.py-$pkgver python2-path.py-$pkgver
}

package_python-path() {
  cd "$srcdir/path.py-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=0
  install -d "$pkgdir/usr/share/licenses/$pkgname/"
  head -n 21 path.py > "$pkgdir/usr/share/licenses/$pkgname/license.txt"
}

package_python2-path() {
  depends=('python2')
  cd "$srcdir/python2-path.py-$pkgver"
  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=0
  install -d "$pkgdir/usr/share/licenses/$pkgname/"
  head -n 21 path.py > "$pkgdir/usr/share/licenses/$pkgname/license.txt"
}

