# $Id: PKGBUILD 142467 2015-10-01 16:06:31Z fyan $
# Maintainer: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Limao Luo <luolimao+AUR@gmail.com>

pkgbase=python-jsonpatch
_pkgname=jsonpatch
pkgname=(python-$_pkgname python2-$_pkgname)
pkgver=1.11
pkgrel=2
pkgdesc="Python object model built on JSON schema and JSON patch"
arch=(any)
url=https://github.com/stefankoegl/python-json-patch
license=(BSD)
makedepends=(python2-setuptools python2-jsonschema python-setuptools python-jsonschema)
options=(!emptydirs)
source=(http://pypi.python.org/packages/source/j/${_pkgname#*-}/${_pkgname#*-}-$pkgver.tar.gz)
sha256sums=('22d0bc0f5522a4a03dd9fb4c4cdf7c1f03256546c88be4c61e5ceabd22280e47')
sha512sums=('516b6d8c32e97056af3c8d89eb49445d334ddc5588238d062476cb942d919436ea390449fa8e98332c571242a8f10aabd0fe7da3a00698ec3fd98e53f286c821')

prepare(){
    cp -a $_pkgname-$pkgver $_pkgname-$pkgver-2
    find $_pkgname-$pkgver-2 -name \*.py -exec sed -i '1s/python$/&2/' {} +
}

build() {
    LANG=en_US.UTF-8
    cd $srcdir/$_pkgname-$pkgver
    python setup.py build
    cd $srcdir/$_pkgname-$pkgver-2
    python2 setup.py build
}

package_python-jsonpatch() {
    cd $srcdir/$_pkgname-$pkgver
    depends=(python-jsonschema)
    install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
    python setup.py install --prefix=/usr --root="$pkgdir"
}
package_python2-jsonpatch() {
    cd $srcdir/$_pkgname-$pkgver-2
    depends=(python2-jsonschema)
    install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
    python2 setup.py install --prefix=/usr --root="$pkgdir"
    rm $pkgdir/usr/bin/json{diff,patch}
}
