# $Id: PKGBUILD 143951 2015-10-14 01:41:05Z fyan $
# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-hpack
pkgname=(python-hpack python2-hpack)
_pkgname=hpack
pkgver=2.0.0
pkgrel=1
pkgdesc="Pure-Python HPACK header compression"
arch=('any')
url="http://hyper.rtfd.org/"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools')
checkdepends=('python-pytest-runner' 'python2-pytest-runner')
source=("$pkgbase-$pkgver::https://github.com/Lukasa/hpack/archive/v${pkgver}.tar.gz")
sha512sums=('fc88930235d9c41286e13c55f2732094740162c1fdb4f9b55b383311a5412b0a2e2ddecb232a2d9fc9b821eb80b7e305156c4f6018f3e6653d957b72c179a97b')

prepare() {
  cp -a $_pkgname-$pkgver{,-py2}
}

build() {
  cd $_pkgname-$pkgver
  python setup.py build

  cd ../$_pkgname-$pkgver-py2
  python2 setup.py build
}

check() {
  cd $_pkgname-$pkgver
  python setup.py ptr

  cd ../$_pkgname-$pkgver-py2
  python2 setup.py ptr
}

package_python-hpack() {
  depends=('python')

  cd $_pkgname-$pkgver
  python setup.py install -O1 --root "${pkgdir}"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-hpack() {
  depends=('python2')

  cd $_pkgname-$pkgver-py2
  python2 setup.py install -O1 --root "${pkgdir}"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

