# $Id: PKGBUILD 142407 2015-10-01 16:04:08Z fyan $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>

pkgname=python-cchardet
pkgname=(python-cchardet python2-cchardet)
pkgver=1.0.0
pkgrel=2
pkgdesc="Universal encoding detector faster than chardet."
url="http://pypi.python.org/pypi/cchardet/"
makedepends=('cython' 'cython2' 'python-setuptools' 'python2-setuptools')
license=('MIT')
arch=('i686' 'x86_64')
source=(http://pypi.python.org/packages/source/c/cchardet/cchardet-$pkgver.tar.gz)
sha256sums=('98e6dc7ca225abfa7e559a6450404aeb2f5bea0713afd6dd492c1a51cec57e63')

build() {
    cd "$srcdir/cchardet-$pkgver"

    rm -rf ../buildpy3; mkdir ../buildpy3
    python setup.py build -b ../buildpy3

    rm -rf ../buildpy2; mkdir ../buildpy2
    python2 setup.py build -b ../buildpy2
    find ../buildpy2 -name \*.py -exec sed -r 's|^#!(.*)python$|#!\1python2|' -i {} +
}

package_python-cchardet() {
    depends=(python)

    cd "$srcdir/cchardet-$pkgver"
    rm -rf build; ln -s ../buildpy3 build
    python setup.py install --skip-build -O1 --root="$pkgdir"
}

package_python2-cchardet() {
    depends=(python2)

    cd "$srcdir/cchardet-$pkgver"
    rm -rf build; ln -s ../buildpy2 build
    python2 setup.py install --skip-build -O1 --root="$pkgdir"
}

