# $Id: PKGBUILD 143311 2015-10-07 16:45:22Z anatolik $
# Maintainer: Anatol Pomozov

pkgbase=python-autobahn
pkgname=(python-autobahn python2-autobahn)
pkgver=0.10.9
pkgrel=1
pkgdesc='Real-time framework for Web, Mobile & Internet of Things'
arch=(any)
url='http://autobahn.ws/python/'
license=(MIT)
makedepends=(python-setuptools python2-setuptools python-twisted python-six python-txaio python2-twisted python2-six python2-txaio)
source=(https://pypi.python.org/packages/source/a/autobahn/autobahn-$pkgver.tar.gz)
sha1sums=('e1ac0e6547f87c683a3203217f4e20595a9b271f')

prepare() {
  cp -a autobahn-$pkgver{,-py2}
}

build() {
  cd "$srcdir/autobahn-$pkgver"
  python setup.py build

  cd "$srcdir/autobahn-$pkgver-py2"
  python2 setup.py build
}

check() {
  cd "$srcdir/autobahn-$pkgver"
  #It requires python-unittest2 in [community]
  #python setup.py test

  cd "$srcdir/autobahn-$pkgver-py2"
  #python2 setup.py test
}

package_python-autobahn() {
  depends=(python python-twisted python-six python-txaio)

  cd "$srcdir/autobahn-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-autobahn() {
  depends=(python2 python2-twisted python2-six python2-txaio)

  cd "$srcdir/autobahn-$pkgver-py2"
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
