# $Id: PKGBUILD 135984 2015-06-28 09:42:07Z bluewind $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Charles Mauch <cmauch@gmail.com>

pkgname=perl-mail-box-parser-c
pkgver=3.007
pkgrel=3
pkgdesc="Perl/CPAN Module Mail::Box::Parser::C : extends MailBox with the speed of C"
arch=("i686" "x86_64")
url="http://search.cpan.org/dist/Mail-Box-Parser-C"
license=("GPL" "PerlArtistic")
options=('!emptydirs')
source=("http://www.cpan.org/authors/id/M/MA/MARKOV/Mail-Box-Parser-C-${pkgver}.tar.gz")
md5sums=('4203b3df229df135ec3488721f0ce7f8')

build() {
  cd Mail-Box-Parser-C-${pkgver}

  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor

  make
}

package() {
  cd Mail-Box-Parser-C-${pkgver}

  make install DESTDIR=${pkgdir}

  find ${pkgdir} -name '.packlist' -delete
  find ${pkgdir} -name '*.pod' -delete
# template start; name=perl-binary-module-dependency; version=1;
if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
	_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
	_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
	depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
fi
# template end;
}
