# $Id: PKGBUILD 145806 2015-11-03 15:04:35Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: hydro <hydro@freenet.de>

pkgname=mediainfo-gui
pkgver=0.7.79
pkgrel=1
pkgdesc="GUI for mediainfo"
arch=('i686' 'x86_64')
url="http://mediainfo.sourceforge.net"
license=('GPL')
depends=('libmediainfo' 'wxgtk' 'libsm' 'desktop-file-utils')
makedepends=('imagemagick')
install=mediainfo-gui.install
source=(http://mediaarea.net/download/source/mediainfo/$pkgver/mediainfo_$pkgver.tar.bz2)
md5sums=('f9ce6df9c3355a16dd3e5fb6f5996d6a')

build() {
  cd MediaInfo/Project/GNU/GUI
  sh ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd MediaInfo/Project/GNU/GUI
  make DESTDIR="$pkgdir" install
  _iconsize=`identify $srcdir/MediaInfo/Source/Resource/Image/MediaInfo.png | grep -oP ' \d+x\d+ ' | tr -d ' '`
  install -Dm 644 "$srcdir/MediaInfo/Source/Resource/Image/MediaInfo.png" \
    "$pkgdir/usr/share/icons/hicolor/${_iconsize}/apps/mediainfo.png"
  install -m 644 "$srcdir/MediaInfo/Source/Resource/Image/MediaInfo."{svg,ico,xpm} "$pkgdir/usr/share/icons/"
  install -Dm 644 "$srcdir/MediaInfo/Source/Resource/Image/MediaInfo.png" \
    "$pkgdir/usr/share/pixmaps/mediainfo-gui.png"
  install -Dm 644 "$srcdir/MediaInfo/Project/GNU/GUI/mediainfo-gui.desktop" \
    "$pkgdir/usr/share/applications/mediainfo-gui.desktop"
}
