# Maintainer : Martin Wimpress <code@flexion.org>

_ver=1.10
_pkgbase=mate-netspeed
pkgname=(${_pkgbase}-gtk3)
pkgver=${_ver}.2
pkgrel=1
pkgdesc="A MATE applet that shows how much traffic occurs on a specified network device. (GTK3 version [EXPERIMENTAL])"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gtk3' 'libgtop' 'mate-panel-gtk3>=1.10' 'wireless_tools')
makedepends=('mate-common' 'yelp-tools')
optdepends=('yelp: for reading MATE help documents')
groups=('mate-extra-gtk3')
conflicts=("${_pkgbase}")
source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
sha1sums=('d140868282415f1bcf067b8d8116fc292aec840d')
install=${_pkgbase}.install

build() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${_pkgbase} \
        --with-gtk=3.0 \
        --disable-static
    make
}

package() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    make DESTDIR="${pkgdir}" install
}
