# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>

pkgname=masscan
pkgver=1.0.3
pkgrel=2
pkgdesc="TCP port scanner, spews SYN packets asynchronously, scanning entire Internet in under 5 minutes"
url="https://github.com/robertdavidgraham/masscan"
arch=('i686' 'x86_64')
license=('AGPL3')
depends=('libpcap')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/robertdavidgraham/${pkgname}/archive/${pkgver}.tar.gz)
sha512sums=('e64b11deaaaa71d5be95e8f2b1fdfa679f5c8e8074c97f9d60d57659f33aec0699673c5aab72824f62d1a8b0e8c9188dcf296dd078bc6c2dbdad95c35c3a5f40')

prepare() {
  cd ${pkgname}-${pkgver}
  # Fix build with GCC 5.x
  sed "s|#elif defined(__GNUC__) && (__GNUC__ == 4)|#elif defined(__GNUC__)|" -i src/string_s.h
  sed -r "s|(CFLAGS )=|\1+=|g" -i Makefile
  cat Makefile
}

build() {
  cd ${pkgname}-${pkgver}
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make regress
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 doc/masscan.8 "${pkgdir}/usr/share/man/man8/masscan.8"
  install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README"
  install -Dm 644 doc/masscan.8.markdown "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
}

# vim: ts=2 sw=2 et:
