# $Id: PKGBUILD 139240 2015-09-05 18:29:36Z jlichtblau $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
# Contributor: Jeff Mickey <jeff@archlinux.org>
# Contributor: sh__

pkgname=libtorrent
pkgver=0.13.6
pkgrel=1
pkgdesc='BitTorrent library with a focus on high performance and good code'
url='http://rakshasa.github.io/rtorrent/'
arch=('i686' 'x86_64')
license=('GPL')
depends=('openssl')
#source=("http://libtorrent.rakshasa.no/downloads/${pkgname}-${pkgver}.tar.gz")
#sha1sums=('3a3ca87054d020bc376abe2c1ea15bbbaef31131')
source=("$pkgname-$pkgver.tar.gz::https://github.com/rakshasa/${pkgname}/archive/${pkgver}.tar.gz")
sha1sums=('9ca6ca9698f81c758fe934b52374f23588a7cc78')

prepare() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	sed '/AM_PATH_CPPUNIT/d' -i configure.ac
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./autogen.sh

	export CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
	./configure \
		--prefix=/usr \
		--disable-debug \

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
}
