# $Id: PKGBUILD 142366 2015-10-01 16:03:01Z fyan $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Roman Kyrylych <roman@archlinux.org>
# Contributor: Tom Killian <tomk@runbox.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=libnewt
pkgver=0.52.18
pkgrel=3
_tclver=8.6
pkgdesc="Not Erik's Windowing Toolkit - text mode windowing with slang"
arch=('x86_64' 'i686')
url='https://fedorahosted.org/newt/'
license=('GPL')
depends=('slang' 'popt' 'gpm')
makedepends=("tcl>=$_tclver" 'python' 'python2')
optdepends=('tcl: whiptcl support' \
            'python: libnewt support with the _snack module'
            'python2: libnewt support with the _snack module')
options=('!makeflags')
source=("https://fedorahosted.org/releases/n/e/newt/newt-$pkgver.tar.gz")
sha256sums=('771b0e634ede56ae6a6acd910728bb5832ac13ddb0d1d27919d2498dab70c91e')

prepare() {
  cd "newt-$pkgver"

  sed -i "s:tcl8.4:tcl$_tclver:" Makefile.in
  echo '#define USE_INTERP_RESULT 1' >> config.h
}

build() {
  cd "newt-$pkgver"

  ./configure --prefix=/usr --with-gpm-support
  make
}

package() {
  make -C "newt-$pkgver" prefix="$pkgdir/usr" install
}

# getver: https://git.fedorahosted.org/cgit/newt.git/plain/CHANGES
# vim:set ts=2 sw=2 et:
