# $Id: PKGBUILD 143859 2015-10-13 05:45:12Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Corrado Primier <bardo@aur.archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>

pkgname=gammu
pkgver=1.36.6
pkgrel=1
pkgdesc="GNU All Mobile Management Utilities"
arch=('i686' 'x86_64')
url="http://wammu.eu/gammu/"
license=('GPL')
depends=('glib2' 'bluez-libs' 'curl' 'libmariadbclient' 'postgresql-libs' 'libusb' 'libgudev')
makedepends=('cmake' 'doxygen' 'mariadb' 'python2')
optdepends=('dialog: support for the gammu-config script' 'python2: for python bindings')
source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.xz)
md5sums=('9047f0598602144a99153f5e61104529')

build() {
  cd "$pkgname-$pkgver"

  # bash completion dir change
  sed -i 's,COMPLETIONSDIR "/etc/bash_completion.d",COMPLETIONSDIR "/usr/share/bash-completion/completions",' contrib/CMakeLists.txt

  cmake . -DCMAKE_INSTALL_PREFIX="/usr" -DLIB_SUFFIX=""

  make
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
