# $Id: PKGBUILD 145700 2015-11-02 19:33:50Z seblu $
# Maintainer: Sébastien Luttringer
# Contributor: Balwinder S "bsd" Dheeman (bdheeman AT gmail.com)

pkgname=dkms
pkgver=2.2.0.3+git151023
pkgrel=1
pkgdesc='Dynamic Kernel Modules System'
arch=('any')
url='http://linux.dell.com/dkms/'
license=('GPL2')
depends=('bash' 'kmod' 'gcc' 'make' 'patch')
makedepends=('git')
optdepends=('linux-headers: build modules against Arch kernel'
            'linux-lts-headers: build modules against LTS Arch kernel')
backup=('etc/dkms/framework.conf' 'etc/default/dkms')
install=$pkgname.install
source=('git+git://linux.dell.com/dkms.git#commit=7b6e78f'
        '02-no-kernel-hook.patch'
        "$pkgname.default"
        "$pkgname.service"
        "$pkgname.systemd")
md5sums=('SKIP'
         '82d520c39c99c34977e48b313a189c6c'
         '33be2fbf1bcc1b3fb2f38d9e7eaa809d'
         '02e9744e3fdc3d2f68e46966fb32e260'
         '0158265dace30b6cdd06244e844b3e5f')

prepare() {
  cd dkms
  # patching
  patches=("$srcdir"/*.patch)
  if (( ${#patches[*]} > 0 )); then
    for p in "${patches[@]}"; do
      msg2 "Apply patch: ${p##*/}"
      patch -p1 -i "$p"
    done
  fi
  # /usr move
  msg2 '/usr move patching'
  for i in dkms{,_framework.conf,.bash-completion,.8,_common.postinst}; do
    sed -ri 's,/lib/modules,/usr/lib/modules,g' "$i"
  done
}

package() {
  # systemd
  install -D -m 644 $pkgname.service "$pkgdir/usr/lib/systemd/system/$pkgname.service"
  install -D -m 755 $pkgname.systemd "$pkgdir/usr/lib/systemd/scripts/$pkgname"
  install -D -m 644 $pkgname.default "$pkgdir/etc/default/$pkgname"
  # upstream installer
  cd dkms
  make \
    DESTDIR="$pkgdir" \
    SBIN="$pkgdir/usr/bin" \
    BASHDIR="$pkgdir/usr/share/bash-completion/completions" \
    install
}

# vim:set ts=2 sw=2 et:
