# $Id: PKGBUILD 140458 2015-09-17 20:51:27Z foutrelis $
# Maintainer: Xyne <ca dot archlinux at xyne, backwards>
# Contributor:  Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Aaron Griffin <aaron@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>

pkgname=cmus
pkgver=2.7.1
pkgrel=2
pkgdesc='Feature-rich ncurses-based music player'
arch=('i686' 'x86_64')
url="https://cmus.github.io/"
license=('GPL')
depends=('ncurses' 'libcue' 'libdiscid')
makedepends=(
  'faad2'
  'ffmpeg'
  'flac'
  'libao'
  'libcdio-paranoia'
  'libmad'
  'libmodplug'
  'libmp4v2'
  'libmpcdec'
  'libpulse'
  'libvorbis'
  'opusfile'
  'wavpack'
)
optdepends=('alsa-lib: for ALSA output plugin support'
            'libao: for AO output plugin support'
            'libpulse: for PulseAudio output plugin support'
            'faad2: for AAC input plugin support'
            'ffmpeg: for ffmpeg input plugin support'
            'flac: for flac input plugin support'
            'libmad: for mp3 input plugin support'
            'libmodplug: for modplug input plugin support'
            'libmp4v2: for mp4 input plugin support'
            'libmpcdec: for musepack input plugin support'
            'libvorbis: for vorbis input plugin support'
            'libcdio-paranoia: for cdio support'
            'opusfile: for opus input plugin support'
            'wavpack: for wavpack input plugin support')
source=("$pkgname-$pkgver.tar.gz::https://github.com/cmus/cmus/archive/v${pkgver}.tar.gz")
sha256sums=('8179a7a843d257ddb585f4c65599844bc0e516fe85e97f6f87a7ceade4eb5165')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 contrib/_cmus "$pkgdir"/usr/share/zsh/site-functions/_cmus
}
