# $Id: PKGBUILD 138572 2015-08-20 21:17:43Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgname=vapoursynth-plugin-mvtools
pkgver=9
pkgrel=1
pkgdesc='MVTools plugin for VapourSynth'
arch=('i686' 'x86_64')
url='https://github.com/dubhater/vapoursynth-mvtools'
license=('GPL2')
depends=('fftw' 'vapoursynth')
makedepends=('yasm')
source=("vapoursynth-plugin-mvtools-${pkgver}.tar.gz::https://github.com/dubhater/vapoursynth-mvtools/archive/v${pkgver}.tar.gz")
sha256sums=('e417764cddcc2b24ee5a91c1136e95237ce1424f5d7f49ceb62ff092db18d907')

build() {
  cd vapoursynth-mvtools-${pkgver}

  ./autogen.sh
  ./configure \
    --prefix='/usr' \
    --libdir='/usr/lib/vapoursynth'
  make
}

package(){
  cd vapoursynth-mvtools-${pkgver}

  make DESTDIR="${pkgdir}" install

  install -dm 755 "${pkgdir}"/usr/share/doc/vapoursynth/plugins/mvtools
  install -m 644 readme.rst "${pkgdir}"/usr/share/doc/vapoursynth/plugins/mvtools/README
}

#vim: ts=2 sw=2 et:
