# $Id: PKGBUILD 135510 2015-06-17 11:07:26Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Lucky <archlinux@builds.lucky.li>
# Contributor: Farhad Shahbazi <farhad@enthusiasm.cc>

pkgname=puddletag
pkgver=1.0.5
pkgrel=2
pkgdesc='A tag editor for GNU/Linux'
url='http://puddletag.sourceforge.net'
license=('GPL')
arch=('any')
depends=('chromaprint' 'mutagen' 'python2-configobj' 'python2-musicbrainz2'
         'python2-pyparsing' 'python2-pyqt4')
optdepends=('python2-pillow: FLAC cover art'
            'quodlibet: QuodLibet library support')
source=("http://sourceforge.net/projects/puddletag/files/puddletag-${pkgver}.tar.gz"
        'puddletag-pyqt4.11.4.patch')
sha256sums=('4698d5effe8f265446b356068bad7ced0b29c1f66824dc94a5688f3fffc389e2'
            'fce0cfce4d4477cde4827a0a4d3ef74fbabf630ada2d0cf035cf155a17c37a68')

prepare() {
  cd puddletag-${pkgver}

  patch -Np2 -i ../puddletag-pyqt4.11.4.patch
  sed -i 's|^#!.*python$|#!/usr/bin/python2|' $(grep -rl '^#!.*python')
}

build() {
  cd puddletag-${pkgver}

  python2 setup.py config
}

package() {
  cd puddletag-${pkgver}

  python2 setup.py install --root="${pkgdir}" --optimize='1'
}

# vim: ts=2 sw=2 et:
