# $Id: PKGBUILD 135950 2015-06-28 09:41:27Z bluewind $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Charles Mauch <cmauch@gmail.com>

pkgname=perl-crypt-blowfish
pkgver=2.14
pkgrel=3
pkgdesc="Perl/CPAN Module Crypt::Blowfish : XSbased implementation of Blowfish"
arch=("i686" "x86_64")
url="http://search.cpan.org/dist/Crypt-Blowfish"
license=("GPL" "PerlArtistic")
source=("http://search.cpan.org/CPAN/authors/id/D/DP/DPARIS/Crypt-Blowfish-$pkgver.tar.gz")
md5sums=('792b43cd4e49d2c2cf4a9f6990ff7d1b')

build() {
  cd $srcdir/Crypt-Blowfish-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor 
  make
}

package() {
  cd $srcdir/Crypt-Blowfish-$pkgver
  make pure_install doc_install DESTDIR=$pkgdir
  find $pkgdir -name '.packlist' -delete
  find $pkgdir -name '*.pod' -delete
# template start; name=perl-binary-module-dependency; version=1;
if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
	_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
	_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
	depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
fi
# template end;
}
