# Maintainer : Martin Wimpress <code@flexion.org>

_ver=1.10
_pkgbase=mate-settings-daemon
pkgname=(${_pkgbase}-gtk3)
pkgver=${_ver}.2
pkgrel=1
pkgdesc="The MATE Settings daemon (GTK3 version [EXPERIMENTAL])"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('dbus-glib' 'dconf' 'fontconfig' 'gtk3' 'libcanberra-pulse'
         'libmatekbd-gtk3>=1.10' 'libmatemixer' 'libnotify' 'libxt'
         'mate-desktop-gtk3>=1.10' 'nss' 'polkit')
makedepends=('mate-common')
groups=('mate-gtk3')
conflicts=("${_pkgbase}" "${_pkgbase}-gstreamer" "${_pkgbase}-pulseaudio")
source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
sha1sums=('9d2291f236ab72b1abdcdb19b878679774652c3a')
install=${_pkgbase}.install

build() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${_pkgbase} \
        --sysconfdir=/etc \
        --with-gtk=3.0 \
        --enable-polkit \
        --disable-static
    make
}

package() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    make DESTDIR="${pkgdir}" install
}
