# $Id: PKGBUILD 134048 2015-05-25 11:05:08Z ttoepper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>

pkgname=i3lock
pkgver=2.7
pkgrel=1
pkgdesc="An improved screenlocker based upon XCB and PAM"
arch=('i686' 'x86_64')
url="http://i3wm.org/i3lock/"
license=('MIT')
groups=("i3")
depends=('xcb-util-image' 'libev' 'cairo' 'libxkbcommon-x11')
options=('docs')
backup=("etc/pam.d/i3lock")
source=("http://i3wm.org/i3lock/$pkgname-$pkgver.tar.bz2"
        "http://i3wm.org/i3lock/$pkgname-$pkgver.tar.bz2.asc")
md5sums=('7ac6cc52a08be10536d3f8d32cb83b45' 'SKIP')
validpgpkeys=('424E14D703E7C6D43D9D6F364E7160ED4AC8EE1D') # Michael Stapelberg

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  
  # Fix ticket FS#31544, sed line taken from gentoo
  sed -i -e 's:login:system-auth:' i3lock.pam

  make
  gzip i3lock.1
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  
  install -Dm644 i3lock.1.gz ${pkgdir}/usr/share/man/man1/i3lock.1.gz
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  make clean
}

# vim:set ts=2 sw=2 et:

