# $Id: PKGBUILD 131688 2015-04-19 11:29:43Z andyrtr $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: William Rea <sillywilly@gmail.com>

pkgname=gwenhywfar
pkgver=4.13.1
_dnrel=78
pkgrel=2
pkgdesc="OS abstraction functions for various projects"
arch=(i686 x86_64)
url="http://www.aquamaniac.de"
license=("LGPL")
depends=('openssl' 'gnutls' 'libgcrypt')
makedepends=('gtk2' 'qt4')
optdepends=('gtk2' 'qt4')
source=("gwenhywfar-$pkgver.tar.gz::http://www2.aquamaniac.de/sites/download/download.php?package=01&release=${_dnrel}&file=01&dummy=gwenhywfar-$pkgver.tar.gz"
	"gnutls.patch")
md5sums=('231b4af546c791a85d0f042773e6bd82'
         '1197ac1f8378b3b3a8ed12169fcb57f9')

prepare() {
  cd $srcdir/gwenhywfar-$pkgver
  patch -p1 <$srcdir/gnutls.patch
}

build() {
  pacman -Q gwenhywfar && return 1
  cd $srcdir/gwenhywfar-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --enable-ssl
  sed -i 's|gnutls_transport_set_lowat||g' src/sio/syncio_tls.c
  make
}

package() {
  cd $srcdir/gwenhywfar-$pkgver
  make DESTDIR=$pkgdir install
}
