# $Id: PKGBUILD 136762 2015-07-13 10:00:27Z aginiewicz $
# Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Atlanis <emallson@archlinux.us>

pkgbase=python-oauth2client
pkgname=('python2-oauth2client' 'python-oauth2client')
pkgver=1.4.12
pkgrel=1
pkgdesc="A client library for OAuth 2.0"
arch=('any')
url="https://github.com/google/oauth2client"
license=('Apache')
makedepends=('python2-setuptools' 'python-setuptools' 'python-httplib2'
             'python-pyasn1' 'python-pyasn1-modules' 'python-rsa'
             'python-six' 'python2-httplib2' 'python2-pyasn1'
             'python2-pyasn1-modules' 'python2-rsa' 'python2-six')
source=("https://pypi.python.org/packages/source/o/oauth2client/oauth2client-${pkgver}.tar.gz")
md5sums=('829a05a559b43215d67947aaff9c11b5')

prepare() {
  cd "$srcdir"

  cp -a oauth2client-${pkgver} oauth2client-py2-${pkgver}
  cd oauth2client-py2-${pkgver}

  sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
      -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
      -e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
      -i $(find . -name '*.py')
}

build() {
  msg "Building Python2"
  cd "$srcdir"/oauth2client-py2-${pkgver}
  python2 setup.py build

  msg "Building Python3"
  cd "$srcdir"/oauth2client-${pkgver}
  python setup.py build
}

package_python2-oauth2client() {
  depends=('python2-httplib2' 'python2-pyasn1' 'python2-pyasn1-modules' 'python2-rsa' 'python2-six')
  optdepends=('python2-gflags: for oauth2client.tools.run function')

  cd "$srcdir"/oauth2client-py2-${pkgver}

  python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
}

package_python-oauth2client() {
  depends=('python-httplib2' 'python-pyasn1' 'python-pyasn1-modules' 'python-rsa' 'python-six')

  cd "$srcdir"/oauth2client-${pkgver}

  python setup.py install --skip-build --root="$pkgdir" --optimize=1
}

