# $Id: PKGBUILD 137806 2015-08-03 11:01:26Z spupykin $
# Maintainer: Kaiting Chen <kaitocracy@gmail.com>
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>
# Contributor: William Rea <sillywilly@gmail.com>

pkgbase=python-bsddb
pkgname=('python2-bsddb' 'python-bsddb')
pkgver=6.1.0
pkgrel=1
pkgdesc="Python interface for BerkeleyDB"
license=('MIT')
arch=('i686' 'x86_64')
url="http://www.jcea.es/programacion/pybsddb.htm"
makedepends=('python2-setuptools' 'python-setuptools')
source=(http://pypi.python.org/packages/source/b/bsddb3/bsddb3-${pkgver}.tar.gz
        LICENSE)
sha1sums=('ca5c204b2c9cf4fff396ba3d49994fe1a95d669f'
          'ef4e4caf618781104dbf5824279ed39d127b4713')
sha1sums=('c12e47f7c21b4bc586c68cce64e0079d070312e8'
          'ef4e4caf618781104dbf5824279ed39d127b4713')
sha1sums=('9b22841ee74bc170f12e80e01567891e3432f442'
          'ef4e4caf618781104dbf5824279ed39d127b4713')

prepare() {
  cp -r bsddb3-${pkgver}{,-python2}
  cd bsddb3-${pkgver}-python2
  sed -i 's|/usr/bin/env python|/usr/bin/env python2|' \
    Lib{,3}/bsddb/{dbshelve.py,test/test_dbtables.py}
}

build () {
  # Build python 3 module
  cd bsddb3-${pkgver}
  python3 setup.py --berkeley-db=/usr build

  # Build python 2 module
  cd ../bsddb3-${pkgver}-python2
  python2 setup.py --berkeley-db=/usr build
}

package_python2-bsddb() {
  depends=('db' 'python2>=2.7')
  cd bsddb3-${pkgver}-python2

  python2 setup.py --berkeley-db=/usr install --root="${pkgdir}" --skip-build --optimize=1
  install -Dm644 "${srcdir}"/LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}

package_python-bsddb() {
  depends=('db' 'python>=3.3')
  cd bsddb3-${pkgver}

  python3 setup.py --berkeley-db=/usr install --root="${pkgdir}" --skip-build --optimize=1
  install -Dm644 "${srcdir}"/LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
