# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: HuntXu <huntxu@live.cn>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=pngcrush
pkgver=1.7.85
pkgrel=2
pkgdesc="A tool for optimizing the compression of PNG files"
url="http://pmt.sourceforge.net/pngcrush"
arch=('i686' 'x86_64')
license=('custom')
depends=('libpng')
source=(http://downloads.sourceforge.net/pmt/${pkgname}-${pkgver}-nolib.tar.xz
        LICENSE)
sha512sums=('7b959fc6a8839fb0dab6471b13e866e11d5fefa072d6b135c7f621bd4b475765c2e8d0b471f074b6df7d6ccd8b5c33938e1143fb2e013986c4e8e5fada68c8ca'
            'f18613b9da9b4f31a317411e726def5122246087ff57887fba6b46f0a7a7fae7109388ecb2ce049bbe992cc6ef0a3fbbe0f5c5bc816705efd7583836cbd4e69d')

prepare() {
  cd ${pkgname}-${pkgver}-nolib
  sed -r "s/^(CFLAGS = .*)$/\\1 ${CFLAGS}/" -i Makefile
  sed -r "s/^(LDFLAGS =*)$/\\1 ${LDFLAGS}/" -i Makefile
}

build() {
  cd ${pkgname}-${pkgver}-nolib
  make
}

package() {
  cd ${pkgname}-${pkgver}-nolib
  make DESTDIR="${pkgdir}" install
  install -Dm 644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et:
