# $Id: PKGBUILD 135976 2015-06-28 09:41:58Z bluewind $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Charles Mauch <cmauch@gmail.com>

pkgname=perl-html-strip
pkgver=2.08
pkgrel=2
pkgdesc="Perl/CPAN Module HTML::Strip"
arch=('i686' 'x86_64')
url="http://search.cpan.org/~kilinrax/HTML-Strip/"
license=("GPL" "PerlArtistic")
depends=('perl')
source=("http://www.cpan.org/authors/id/K/KI/KILINRAX/HTML-Strip-$pkgver.tar.gz")
md5sums=('39ea9dfb58e9cc2db13916be805e0a55')

build() {
  cd $srcdir/HTML-Strip-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}
package() {
  cd $srcdir/HTML-Strip-$pkgver
  make install DESTDIR=$pkgdir
  find $pkgdir -name '.packlist' -delete
  find $pkgdir -name '*.pod' -delete
# template start; name=perl-binary-module-dependency; version=1;
if [[ $(find "$pkgdir/usr/lib/perl5/" -name "*.so") ]]; then
	_perlver_min=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]);')
	_perlver_max=$(perl -e '$v = $^V->{version}; print $v->[0].".".($v->[1]+1);')
	depends+=("perl>=$_perlver_min" "perl<$_perlver_max")
fi
# template end;
}
