# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Ondrej Martinak <omartinak@gmail.com>

pkgname=libxdg-basedir
pkgver=1.2.0
pkgrel=3
pkgdesc="An implementation of the XDG Base Directory specifications."
arch=('i686' 'x86_64')
#url="http://n.ethz.ch/student/nevillm/download/libxdg-basedir"
url="https://github.com/devnev/$pkgname"
license=('MIT')
depends=('glibc')
source=(https://github.com/devnev/$pkgname/archive/$pkgname-$pkgver.tar.gz
        'xdgGetRelativeHome-overflow.patch'
        'LICENSE')
sha1sums=('e671b01b17c8cf785d95dd3aefa93e7cf31e56a5'
          '90ce224344f8075c4ce8241b8f8bf13b8968eec5'
          'c76efede60d0632d4241d718919d8b4ec62056b3')

prepare() {
   cd "${srcdir}/$pkgname-$pkgname-$pkgver"

#   FS#39490: Fix buffer overflow
   patch -Np0 -i "${srcdir}/xdgGetRelativeHome-overflow.patch"
}

build() {
   cd "${srcdir}/$pkgname-$pkgname-$pkgver"
   ./autogen.sh --prefix=/usr
   make
}

package() {
   cd "${srcdir}/$pkgname-$pkgname-$pkgver"
   make DESTDIR=${pkgdir} install

   # Install MIT license
   install -Dm644 ${srcdir}/LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}

