# $Id: PKGBUILD 228769 2015-01-09 00:30:25Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgbase=nbxmpp
pkgname=('python-nbxmpp' 'python2-nbxmpp')
pkgver=0.5.2
pkgrel=1
arch=('any')
url="https://python-nbxmpp.gajim.org/"
license=('GPL3')
makedepends=('python' 'python2')
source=($pkgbase-$pkgver.tar.gz::https://python-nbxmpp.gajim.org/downloads/7)
sha1sums=('b8924c5aa5dca2d1a0b6c6cd8e6ec71e5e42bbea')

prepare() {
  cp -r ${pkgbase}-${pkgver} ${pkgbase}-${pkgver}-python2
}

build() {
  cd ${pkgbase}-${pkgver}-python2
  python2 setup.py build
  cd ../${pkgbase}-${pkgver}
  python setup.py build
}

package_python-nbxmpp() {
  pkgdesc="A Python 3 library to use Jabber/XMPP networks in a non-blocking way"
  depends=('python')
  cd ${pkgbase}-${pkgver}
  python setup.py install --root="${pkgdir}"
}

package_python2-nbxmpp() {
  pkgdesc="A Python 2 library to use Jabber/XMPP networks in a non-blocking way"
  depends=('python2')
  cd ${pkgbase}-${pkgver}-python2
  python2 setup.py install --root="${pkgdir}"
}
