# $Id: PKGBUILD 239724 2015-05-24 16:48:03Z arojas $
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: ice-man <icemanf@gmail.com>
# Contributor: sergeantspoon <sergeantspoon@archlinux.us>

pkgname=libssh
pkgver=0.7.0
pkgrel=2
pkgdesc="Library for accessing ssh client services through C libraries"
url="http://www.libssh.org/"
license=('LGPL')
arch=('i686' 'x86_64')
depends=('openssl')
makedepends=('cmake' 'cmocka' 'doxygen')
checkdepends=('openssh')
source=(https://red.libssh.org/attachments/download/140/${pkgname}-${pkgver}.tar.xz
        https://red.libssh.org/attachments/download/139/${pkgname}-${pkgver}.tar.asc 'ssh_forward_listen.patch')
md5sums=('cf20c3bb6edfc853187985c3f649ca80'
         'SKIP'
         '53ddfb95b84530d9bf5947e4dc98a875')
validpgpkeys=('8DFF53E18F2ABC8D8F3C92237EE0FC4DCC014E3D') # Andreas Schneider <asn@cryptomilk.org>

prepare() {
  # disable the test. It is confused by our clean container setup.
  # 'extra-x86-build' uses user 'nobody' that has a record in /etc/passwd file
  # but $HOME envvar is set to '/build'. The test expects that $HOME corresponds to passwd file.
  sed 's/unit_test(torture_path_expand_tilde_unix),//' -i libssh-${pkgver}/tests/unittests/torture_misc.c

# Fix undefined symbol (FS#45055)
  cd $pkgname-$pkgver
  patch -p1 -i "$srcdir"/ssh_forward_listen.patch
}

build() {
  mkdir build || true
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DWITH_GSSAPI=OFF \
    -DWITH_TESTING=ON
  make
}

check() {
  cd build
  make test
}

package(){
  cd build
  make DESTDIR="${pkgdir}" install
}
