# $Id: PKGBUILD 238527 2015-05-05 23:45:45Z heftig $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=libsecret
pkgver=0.18.2
pkgrel=1
pkgdesc='Library for storing and retrieving passwords and other secrets.'
arch=('i686' 'x86_64')
license=('LGPL')
url="https://wiki.gnome.org/Projects/Libsecret"
depends=('glib2' 'libgcrypt')
checkdepends=('python2-dbus' 'dbus-glib' 'python2-gobject2' 'python2-gobject' 'gjs')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection' 'vala')
optdepends=('gnome-keyring: key storage service (or use any other service implementing org.freedesktop.secrets)')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('12fd288b012e1b2b1b54d586cd4c6507885715534644b4534b7ef7d7079ba443')

prepare() {
  mkdir path
  ln -s /usr/bin/python2 path/python
}

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static
  make
}

check() {
  cd "$pkgname-$pkgver"
  PATH="$srcdir/path:$PATH" dbus-run-session make -k check 
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}
