# $Id: PKGBUILD 241587 2015-06-30 21:00:54Z arojas $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kdegraphics-okular
pkgver=15.04.3
pkgrel=1
pkgdesc='Document Viewer'
arch=('i686' 'x86_64')
url="http://kde.org/applications/graphics/okular/"
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdegraphics')
depends=('kdebase-runtime' 'qimageblitz' 'chmlib' 'djvulibre' 'libspectre'
         'libkexiv2' 'poppler-qt4' 'libkscreen4')
makedepends=('cmake' 'automoc4' 'ebook-tools' 'kdegraphics-mobipocket')
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/okular-${pkgver}.tar.xz")
sha1sums=('65b934aad6a57eeb60a8b6e78c6f792b75f5b77b')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../okular-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_ActiveApp=OFF
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}
