# $Id: PKGBUILD 228949 2015-01-12 20:06:03Z tpowa $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=misdnuser
pkgver=2.0.19
pkgrel=2
pkgdesc="Tools and library for mISDN"
arch=('i686' 'x86_64')
url="http://www.misdn.org"
license=('GPL')
makedepends=('git')
depends=('isdn4k-utils' 'spandsp')
backup=('etc/capi20.conf') 
options=('!makeflags' '!strip')
source=(misdnuser::git+git://git.misdn.eu/mISDNuser.git#tag=v${pkgver}
        mISDNcapid.service
        c2faxrecv-mISDNcapid.service
        mISDNcapid.conf)

build() {
  # only enable for debugging!
  #export CFLAGS+=" -g -O0"
  #export CXXFLAGS+=" -g -O0"
  cd ${srcdir}/${pkgname}
  make
  ./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --enable-capi --enable-softdsp --with-mISDN_group=uucp --localstatedir=/var
  make
}

package() {
  cd ${srcdir}/${pkgname}
  make DESTDIR=${pkgdir} install
  # fix udev rule
  mkdir -p ${pkgdir}/usr/lib/udev/rules.d
  mv ${pkgdir}/etc/udev/rules.d/45-misdn.rules ${pkgdir}/usr/lib/udev/rules.d
  rm -r ${pkgdir}/etc/udev/
  # add systemd files
  install -D -m644 ${srcdir}/mISDNcapid.service ${pkgdir}/usr/lib/systemd/system/mISDNcapid.service
  # mISDNcapid:
  # tends to crash on avmfritz card, add an extra systemd file for
  # restarting the services until segfaults are fixed!
  install -D -m644 ${srcdir}/c2faxrecv-mISDNcapid.service ${pkgdir}/usr/lib/systemd/system/c2faxrecv-mISDNcapid.service
  install -D -m644 ${srcdir}/mISDNcapid.conf ${pkgdir}/usr/lib/tmpfiles.d/mISDNcapid.conf
  # remove /var/run/mISDNcapid
  rm -r ${pkgdir}/var
}
md5sums=('SKIP'
         'bfd47480a54b41394ba5cc3f53587130'
         '32ead7f063e007c784aa883d441f33c2'
         '42c3b46880a68c3883ee1ed00af34b45')
