# $Id: PKGBUILD 239463 2015-05-16 16:21:29Z anatolik $
# Maintainer:
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase=lpeg
pkgname=(lua-lpeg lua51-lpeg lua52-lpeg)
pkgver=0.12.2
pkgrel=2
arch=('i686' 'x86_64')
url='http://www.inf.puc-rio.br/~roberto/lpeg'
license=('MIT')
makedepends=('lua' 'lua51' 'lua52')
source=(http://www.inf.puc-rio.br/~roberto/$pkgbase/$pkgbase-$pkgver.tar.gz
        LICENSE)
md5sums=('fabb614eb46e370d4f6b8fd82d17ca7e'
         'dccb97b431c3a3ccaacc216c6242e9fd')

prepare() {
  sed 's/^CFLAGS =/CFLAGS +=/' -i $pkgbase-$pkgver/makefile
  sed 's/^COPT =/# COPT =/' -i $pkgbase-$pkgver/makefile

  cp -r $pkgbase-$pkgver $pkgbase-$pkgver-51
  cp -r $pkgbase-$pkgver $pkgbase-$pkgver-52
}

build() {
  cd $pkgbase-$pkgver
  make LUADIR=/usr/include

  cd "$srcdir"/$pkgbase-$pkgver-51
  make LUADIR=/usr/include/lua5.1

  cd "$srcdir"/$pkgbase-$pkgver-52
  make LUADIR=/usr/include/lua5.2
}

check() {
  msg2 "Testing with Lua 5.3"
  cd $srcdir/$pkgbase-$pkgver
  lua test.lua

  msg2 "Testing with Lua 5.1"
  cd $srcdir/$pkgbase-$pkgver-51
  lua5.1 test.lua

  msg2 "Testing with Lua 5.2"
  cd $srcdir/$pkgbase-$pkgver-52
  lua5.2 test.lua
}

package_lua-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.3'
  depends=('lua')

  cd $pkgbase-$pkgver
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.3/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.3/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua51-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.1'
  depends=('lua51')

  cd $pkgbase-$pkgver-51
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.1/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.1/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua52-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.2'
  depends=('lua52')

  cd $pkgbase-$pkgver-52
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.2/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.2/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
