# $Id: PKGBUILD 239462 2015-05-16 16:21:28Z anatolik $
# Maintainer: speps <speps at aur dot archlinux dot org>
# Maintainer: Sébastien Luttringer

pkgbase=lgi
pkgname=(lua-lgi)
pkgver=0.9.0
pkgrel=1
pkgdesc='Lua bindings for gnome/gobject using gobject-introspection library'
arch=(i686 x86_64)
url='https://github.com/pavouk/lgi'
license=('custom:MIT')
depends=('glibc' 'glib2' 'libffi' 'lua' 'gobject-introspection-runtime')
makedepends=('gobject-introspection')
replaces=('lgi')
conflicts=('lgi')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/pavouk/$pkgbase/archive/$pkgver.tar.gz")
md5sums=('cc433a597f23cfabdfc905c6c2cd3d7c')

build() {
  cd $pkgbase-$pkgver
  make
}

package_lua-lgi() {
  cd $pkgbase-$pkgver
  make \
    LUA_LIBDIR=/usr/lib/lua/5.3 \
    LUA_SHAREDIR=/usr/share/lua/5.3 \
    DESTDIR="$pkgdir/" install

  # dump typelib tool
  install -Dm755 tools/dump-typelib.lua \
    "$pkgdir/usr/bin/dump-typelib"

  # docs
  install -d "$pkgdir/usr/share/doc/$pkgname"
  install -Dm644 docs/* \
    "$pkgdir/usr/share/doc/$pkgname"

  # samples
  install -d "$pkgdir/usr/share/$pkgname/samples/gtk-demo"
  install -Dm644 samples/*.lua \
    "$pkgdir/usr/share/$pkgname/samples"
  install -Dm644 samples/gtk-demo/* \
    "$pkgdir/usr/share/$pkgname/samples/gtk-demo"

  # license
  install -Dm644 LICENSE \
    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et:
