# $Id: PKGBUILD 240054 2015-06-02 06:57:10Z arojas $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>

pkgname=kig
pkgver=15.04.2
pkgrel=1
pkgdesc="Interactive Geometry"
url="http://kde.org/applications/education/kig/"
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdeedu')
depends=('ktexteditor' 'kdelibs4support' 'boost-libs')
makedepends=('extra-cmake-modules' 'kdoctools' 'python' 'python2' 'boost')
replaces=('kdeedu-kig')
conflicts=('kdeedu-kig')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/kig-${pkgver}.tar.xz")
sha1sums=('9dbc2dd6d5997058c2bbda7e02d62773ce93a806')

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../kig-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DBUILD_TESTING=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install

  # Use the python2 executable
  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' "${pkgdir}"/usr/bin/pykig.py
}
