# $Id: PKGBUILD 231162 2015-02-09 02:58:59Z fyan $
# Maintainer: Ionut Biru <ibiru@archlinux.org>

pkgname=farstream
pkgver=0.2.7
pkgrel=1
pkgdesc="Farstream (formerly Farsight) - Audio/Video Communications Framework"
arch=('i686' 'x86_64')
url="http://www.freedesktop.org/wiki/Software/Farstream"
license=('LGPL')
depends=('gst-plugins-base-libs' 'libnice')
makedepends=('gobject-introspection' 'python2')
optdepends=('gst-plugins-good' 'gst-plugins-bad')
conflicts=('farsight2')
replaces=('farsight2')
source=(http://freedesktop.org/software/$pkgname/releases/$pkgname/$pkgname-$pkgver.tar.gz{,.asc})
md5sums=('bb56af4cbf2cd42f35353f20cf04bc17'
         'SKIP')
validpgpkeys=('DB30B086FAF86CE7296FADC51D388E5A4ED9A2BB')  # Olivier Crête

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
    --with-package-name='Arch Linux farstream package' \
    --with-package-origin='http://archlinux.org'
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:
