# $Id: PKGBUILD 236323 2015-04-12 23:21:59Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=quodlibet
pkgver=3.4.0
pkgrel=1
pkgdesc="An audio library tagger, manager and player"
arch=('any')
license=('GPL2')
url="https://github.com/quodlibet/quodlibet"
depends=('gtk3' 'python2-gobject' 'python2-dbus' 'python2-cairo' 'mutagen' 
         'gst-plugins-base' 'gst-plugins-good' 'gst-plugins-ugly' 
	 'gnome-icon-theme' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('gst-libav: for ffmpeg (ASF/WMA) support'
            'gst-plugins-bad: for Musepack support'
            'libgpod: for ipod support'
            'python2-feedparser: for audio feeds (podcast) support'
            'libkeybinder3: for the multimedia keys support'
            'media-player-info: for media devices support'
            'cddb-py: for "CDDB Lookup" plugin'
            'python2-musicbrainz2: for "MusicBrainz Lookup" plugin'
            'python2-pyinotify: for "Automatic library update" plugin'
	    'kakasi: for "Kana/Kanji Simple Inverter" plugin'
	    'zeitgeist: for "Event Logging" plugin'
            'gst-plugins-bad: for "Audio Pitch/Speed" plugin')
provides=('quodlibet-plugins')
conflicts=('quodlibet-plugins')
replaces=('quodlibet-plugins')
options=('!makeflags')
install=quodlibet.install
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/quodlibet/quodlibet/archive/release-${pkgver}.tar.gz)
sha1sums=('64a8478d91eb9a7ce50b730b9e4a53909419a749')

build() {
  cd ${pkgname}-release-${pkgver}/quodlibet
  python2 setup.py build
}

package() {
  cd ${pkgname}-release-${pkgver}/quodlibet
  python2 setup.py install --root="${pkgdir}"
}
