# Maintainer: Florian Pritz <bluewind@xinu.at>

pkgname=perl-crypt-openssl-random
pkgver=0.10
pkgrel=1
pkgdesc='Routines for accessing the OpenSSL pseudo-random number generator'
arch=(i686 x86_64)
license=(PerlArtistic GPL)
options=(!emptydirs)
depends=(perl openssl)
url=https://metacpan.org/release/Crypt-OpenSSL-Random
source=("http://search.cpan.org/CPAN/authors/id/R/RU/RURBAN/Crypt-OpenSSL-Random-$pkgver.tar.gz")
md5sums=(b89ca9314c3a066b440a7bb3cb8d725d)
sha512sums=(e1fd1de82910a58c3f40e097fab6bfde9fb6162b07ebeadd16ff406a547fbd9c0cf5b0d46bba13093a00d9fac0044d9b793668411dd758c0169512d79b8bc691)
_ddir="Crypt-OpenSSL-Random-$pkgver"

build()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  unset PERL5LIB PERL_MM_OPT
  /usr/bin/perl Makefile.PL
  make
)

check()
(
  cd "$srcdir/$_ddir"
  export PERL_MM_USE_DEFAULT=1
  unset PERL5LIB
  make test
)

package()
(
  cd "$srcdir/$_ddir"
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
)

# Local Variables:
# mode: shell-script
# sh-basic-offset: 2
# End:
# vim:set ts=2 sw=2 et:
