# $Id: PKGBUILD 232404 2015-03-02 03:51:49Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>

pkgname=liferea
pkgver=1.10.14
pkgrel=1
pkgdesc="A desktop news aggregator for online news feeds and weblogs"
arch=('i686' 'x86_64')
url="http://liferea.sourceforge.net/"
license=('GPL')
depends=('webkitgtk' 'libnotify' 'json-glib' 'libpeas' 'python2-gobject' 
         'gnome-icon-theme' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('gnome-keyring: for keyring plugin support'
            'libgnome-keyring: for keyring plugin support'
	    'gst-plugins-base: for media player plugin support'
	    'gst-plugins-good: for media player plugin support'
	    'gst-plugins-bad: for media player plugin support')
options=('!emptydirs')
install=liferea.install
source=(https://github.com/lwindolf/liferea/releases/download/v${pkgver}/liferea-${pkgver}.tar.bz2)
sha1sums=('ffdd505d01473b1ec29a3da292632f474b9b83fb')

build() {
  cd liferea-${pkgver}
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-schemas-compile
  make
}

package() {
  cd liferea-${pkgver}
  make DESTDIR="${pkgdir}" install
}
