# $Id: PKGBUILD 235598 2015-04-07 20:01:46Z arojas $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Antonio Rojas < arojas@archlinux.org >

pkgname=kdeplasma-applets-plasma-nm
pkgver=0.9.3.6
pkgrel=1
pkgdesc="Plasma applet written in QML for managing network connections"
arch=('i686' 'x86_64')
url="https://projects.kde.org/projects/kde/workspace/plasma-nm"
license=('GPL')
depends=('kdebase-workspace' 'libnm-qt4')
makedepends=('cmake' 'automoc4' 'openconnect' 'mobile-broadband-provider-info')
optdepends=('mobile-broadband-provider-info: Database of mobile broadband service providers'
            'openconnect: Cisco AnyConnect VPN plugin')
conflicts=('kdeplasma-applets-networkmanagement')
source=("http://download.kde.org/stable/plasma-nm/plasma-nm-${pkgver}.tar.xz")
md5sums=('ab94be59919eca6bf89fc1930cf3dd39')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../plasma-nm-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}
