# $Id: PKGBUILD 237476 2015-04-19 15:52:56Z arojas $
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgbase=kdebase
pkgname=('kdebase-dolphin'
         'kdebase-kdepasswd'
         'kdebase-kdialog'
         'kdebase-keditbookmarks'
         'kdebase-kfind'
         'kdebase-konq-plugins'
         'kdebase-konqueror'
         'kdebase-lib'
         'kdebase-plasma')
pkgver=15.04.0
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdebase')
makedepends=('kdelibs' 'cmake' 'automoc4' 'tidyhtml' 'baloo4-widgets')
source=("http://download.kde.org/stable/applications/${pkgver}/src/kde-baseapps-${pkgver}.tar.xz")
sha1sums=('18ec78a547ca68b110d3b82a12a0001bf62d0b66')

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../kde-baseapps-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package_kdebase-dolphin() {
  pkgdesc='File Manager'
  depends=('kdebase-runtime' 'kdebase-lib' 'baloo4-widgets')
  optdepends=('kdegraphics-svgpart: thumbailers for SVG files'
              'kdegraphics-thumbnailers: thumbnailers for various graphics files'
              'kdemultimedia-ffmpegthumbs: thumbnailers for video files'
              'kdemultimedia-mplayerthumbs: thumbnailers for video files'
              'kdesdk-thumbnailers: thumbnailers for development files'
              'icoutils: thumbnailers for MS files'
              'ruby: servicemenu installation'
              'konsolepart4: open terminal in context menu')
  url="http://kde.org/applications/system/dolphin/"
  install=kdebase-dolphin.install

  cd "$srcdir"/build/dolphin
  make DESTDIR="$pkgdir" install
  cd "$srcdir"/build/doc/dolphin
  make DESTDIR="$pkgdir" install
}

package_kdebase-kdepasswd() {
  pkgdesc='Change Password'
  depends=('kdebase-runtime' 'kdebase-lib')

  cd "$srcdir"/build/kdepasswd
  make DESTDIR="$pkgdir" install
  cd "$srcdir"/build/doc/kdepasswd
  make DESTDIR="$pkgdir" install
}

package_kdebase-kdialog() {
  pkgdesc='A utility for displaying dialog boxes from shell scripts'
  depends=('kdebase-runtime')

  cd "$srcdir"/build/kdialog
  make DESTDIR="$pkgdir" install
}

package_kdebase-keditbookmarks() {
  pkgdesc='Bookmark Organizer and Editor'
  depends=('kdebase-runtime')

  cd "$srcdir"/build/keditbookmarks
  make DESTDIR="$pkgdir" install
}

package_kdebase-kfind() {
  pkgdesc='Find Files/Folders'
  depends=('kdebase-runtime' 'kdebase-lib')
  url="http://kde.org/applications/utilities/kfind/"
  install='kdebase.install'

  cd "$srcdir"/build/kfind
  make DESTDIR="$pkgdir" install
  cd "$srcdir"/build/doc/kfind
  make DESTDIR="$pkgdir" install
}

package_kdebase-konq-plugins() {
  pkgdesc='Extra plugins for Konqueror'
  depends=('kdebase-konqueror' 'tidyhtml')
  replaces=('konq-plugins')
  install='kdebase.install'

  cd "$srcdir"/build/konq-plugins
  make DESTDIR="$pkgdir" install
}

package_kdebase-konqueror() {
  pkgdesc='KDE File Manager & Web Browser'
  depends=('kdebase-dolphin' 'kdebase-keditbookmarks')
  optdepends=('kwebkitpart: to enable webkit engine')
  url="http://kde.org/applications/internet/konqueror/"
  install='kdebase-konqueror.install'
  conflicts=('kdebase-nsplugins')
  replaces=('kdebase-nsplugins')

  for i in konqueror doc/konqueror nsplugins; do
    cd "$srcdir"/build/${i}
    make DESTDIR="$pkgdir" install
  done
}

package_kdebase-lib() {
  pkgdesc='KDE libraries for the basic desktop applications'
  groups=()
  depends=('kdelibs')

  cd "$srcdir"/build/lib
  make DESTDIR="$pkgdir" install
}

package_kdebase-plasma() {
  pkgdesc='Display the contents of folders (User´s home folder as default)'
  depends=('kdebase-workspace' 'kdebase-lib')

  cd "$srcdir"/build/plasma
  make DESTDIR="$pkgdir" install
}
